Konfigurieren Sie MikroTik hAP mini für IPTV Beeline

Bei der letzten MUM in Moskau wurde mir wie allen anderen der Router MikroTik hAP mini übergeben.

Ich beschloss, sie durch einen alten, ständig hängenden Router von ihren Eltern zu ersetzen.
Um maximale Leistung zu erzielen, entschied ich mich für einen Switch-Chip. Im Internet habe ich keine passende Anweisung gefunden, in der die Einstellungen sowohl für die kabelgebundenen als auch für die drahtlosen Komponenten beschrieben werden. Daher habe ich beschlossen, meine Erfahrungen zu teilen.
Ich bin ein wenig vorausgegangen und möchte sagen, dass hAP mini die Aufgabe perfekt bewältigt hat.

Das Schema



sieht wie folgt aus: Internet und IPTV von Beeline, IPOE-Verbindung. Auf dem ersten Port befindet sich das Internet, auf dem zweiten Port das IPTV-Präfix, auf 3 und auf WLAN-LANs.

Also, los geht's:

1. Ohne den Router mit dem Internet zu verbinden, schalten Sie ihn ein, verbinden Sie ihn über das Kabel mit dem dritten Port, starten Sie die WinBox, gehen Sie zum Router und setzen Sie die Einstellungen zurück. Denken Sie daran, die Erstellung der Sicherung abzubrechen und verwenden Sie die Standardkonfiguration.



2. Stellen Sie nach dem Neustart des Routers erneut eine Verbindung über die Winbox unter der MAC-Adresse her

: 3. Starten Sie das neue Terminal und geben Sie die folgenden Befehle ein:

Der allererste Schritt besteht darin, das Kennwort für den Admin-Benutzer zu ändern.
Erstellen Sie im Idealfall einen anderen Benutzer und löschen Sie ihn.

/user set admin password=qwFnnNn#4$2hWR#QirEx

Erstellen Sie eine Brücke:

/interface bridge add name=bridge1 protocol-mode=none

Fügen Sie der Bridge Schnittstellen hinzu:

/interface bridge port
add bridge=bridge1 interface=ether1
add bridge=bridge1 interface=ether2
add bridge=bridge1 interface=ether3
add bridge=bridge1 interface=wlan1

Wir erstellen zwei zusätzliche Schnittstellen-VLAN auf der Brücke:

/interface vlan
add interface=bridge1 name=VLAN10 vlan-id=10
add interface=bridge1 name=VLAN20 vlan-id=20

Konfigurieren für VLAN-Schnittstellen:

/interface ethernet switch vlan
add independent-learning=yes ports=ether1,ether2,switch1-cpu switch=switch1 vlan-id=10
add independent-learning=yes ports=ether3,switch1-cpu switch=switch1 vlan-id=20
/interface ethernet switch port
set 0 default-vlan-id=10 vlan-header=always-strip vlan-mode=secure
set 1 default-vlan-id=10 vlan-header=always-strip vlan-mode=secure
set 2 default-vlan-id=20 vlan-header=always-strip vlan-mode=secure
set 3 vlan-mode=secure

Konfigurieren Sie WLAN (vergessen Sie nicht die SSID und das Kennwort für Ihren Ersatz):

/interface wireless security-profiles
set [ find default=yes ] authentication-types=wpa2-psk eap-methods="" mode=dynamic-keys wpa2-pre-shared-key=MyWifiPassword
/interface wireless
set [ find default-name=wlan1 ] band=2ghz-onlyn disabled=no mode=ap-bridge ssid=MyWifiName vlan-id=20 vlan-mode=use-tag wireless-protocol=802.11 wps-mode=disabled

Internetverbindung ist IPOE, d. H. Die Adresse wird per DHCP bezogen. Bitte beachten Sie, dass wir den Dhcp-Client im VLAN konfigurieren:

/ip dhcp-client add dhcp-options=hostname,clientid disabled=no interface=VLAN10

Konfigurieren Sie das lokale Netzwerk:

/ip address add address=192.168.11.1/24 interface=VLAN20 network=192.168.11.0
/ip pool add name=pool-lan ranges=192.168.11.2-192.168.11.99
/ip dhcp-server add address-pool=pool-lan disabled=no interface=VLAN20 lease-time=1h name=dhcp-server
/ip dhcp-server network add address=192.168.11.0/24 dns-server=192.168.11.1 gateway=192.168.11.1
/ip dns set allow-remote-requests=yes

Zur Vereinfachung kombinieren wir Schnittstellen in Gruppen:

/interface list
add name=WAN
add name=LAN
/interface list member
add interface=VLAN10 list=WAN
add interface=VLAN20 list=LAN

Erstellen Sie minimale Firewall-Regeln:

/ip firewall filter
add action=accept chain=input comment="Allow icmp" protocol=icmp
add action=accept chain=input comment="Allow established & related" connection-state=established,related
add action=accept chain=input comment="Allow access for ManageIP group" src-address-list=ManageIP
add action=drop chain=input comment="All other drop"
add action=fasttrack-connection chain=forward comment=Fasttrack connection-state=established,related
add action=accept chain=forward comment="Allow established & related" connection-state=established,related,untracked
add action=drop chain=forward comment="Drop invalid connection packets" connection-state=invalid
add action=accept chain=forward comment="Allow Internet"in-interface-list=LAN out-interface-list=WAN
add action=drop chain=forward comment="All other drop"

Fügen Sie der ManageIP-Gruppe die Adressen hinzu, von denen aus auf den Router zugegriffen wird:

/ip firewall address-list add address=192.168.11.0/24 list=ManageIP

NAT für den Zugriff auf das Internet von lokalki konfigurieren:

/ip firewall nat add action=masquerade chain=srcnat out-interface-list=WAN

Nun und zum Schluss nicht zwingend, aber nützliche Befehle:

/ip cloud set ddns-enabled=yes update-time=no
/system clock set time-zone-autodetect=no
/system clock manual set time-zone=+03:00 
/system identity set name=MyHome
/system ntp client set enabled=yes primary-ntp=95.165.138.248 secondary-ntp=89.175.20.7

Wir erlauben die Erkennung von Nachbarn nur aus dem lokalen Netzwerk.

Wenn Sie ROS nicht aktualisiert haben und 6.40.4 installiert haben:

/ip neighbor discovery
set ether1 discover=no
set ether2 discover=no
set ether3 discover=no
set wlan1 discover=no
set bridge1 discover=no

Wenn auf den neuesten Stand gebracht, dann:

/ip neighbor discovery-settings set discover-interface-list=LAN

In diesem Fall funktioniert die MAC-Verbindung vom WLAN-Netzwerk jedoch nicht. Irgendeine Idee warum?

Das ist alles

Sie können das Providerkabel an den ersten Port anschließen und testen.

Die Ergebnisse eines kleinen Tests zeigten, dass das Kabel fast alle 100 Mbps vom Provider erhielt (ein Torrent gestartet), die IPTV-Set-Top-Box funktioniert und der Prozessor nur zu 20% ausgelastet ist. Mit WLAN konnte man nur 25 Mbps erreichen, zu viel Luft ist verschmutzt, aber diese Geschwindigkeit reicht aus.


Jetzt auch beliebt: